Object LibraryMessages
  with before [;
	  Answer, Ask, AskFor, Tell, Order, No, Yes, Sorry: "To speak with someone, use the command TALK WITH <person>.";
 
          Examine:
	    if(lm_n == 1) "You know the darkness intimately, through introspection.";
	  
	  Attack: 
	   if(noun == player) {
	     if(verhaaltracker.status < 7)
	       "You don't want to commit suicide. Not yet.";
	     if(parent(final_scherf) == player)
	       <<AttackWith player final_scherf>>;
	       "You'll need something sharp to kill yourself with.";
	    }
	       
	   if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	     "In a little while, you'll be able to unleash all your violent fantasies onto the baron.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "You must destroy the dragon.";
	   }
	   else 
	     "You have already destroyed too much.";

	  Burn:
	      if(verhaaltracker.status < 5){
	          "Setting things on fire won't help you.";
		} else {  
		  if(verhaaltracker.status < 7){
		    "That is non-flammable.";
		  } else {
		    "Only physical flames, not those that torment your soul, can start fires.";
		  };
		};


	  Jump: 
	   if(verhaaltracker.status < 5 && verhaaltracker.status > 1){
	     "You jump up and down and move your arms a bit. You feel great. Full of strength that wishes to express itself.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "You cannot jump while in this suit of armour.";
	   }
	   else 
	     "Your conscience drags you down.";
	     
	  Kiss:
	   if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	     "Is this a time for romance? Your daughter has been kidnapped.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "Fight first; make love later.";
	   }
	   else 
	     "All things cringe at your touch.";

	  Listen:
	   if(verhaaltracker.status < 7 && verhaaltracker.status > 1){
	     "Your blood pounds in your veins.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "You hear a huge beast breating.";
	   }
	   else 
	     "Nothing. Only, at the edge of hearing, the footsteps of angels--or demons.";
	     
	     
	Miscellany:
	   if(lm_n == 19) {
	     if(verhaaltracker.status == 1 && verhaaltracker.brand == 0) "Your body, your armour, the look on your face: in one word, heroic! You are strong, and quick, and fearless. No mere dragon can stand against you.";
	     
	     if(verhaaltracker.status == 1 && verhaaltracker.brand > 0) "Flames break out of your flesh everywhere, a fire bursting forth from the core of your being.";
	     
	     if(verhaaltracker.status < 7 && kleding has worn) "You look masculine in your rugged lumberjack clothes. Heavy muscles, stubbly beard, strong jaw--what's not to be pleased with?";
	     
	     if(verhaaltracker.status < 7 && kleding hasnt worn && jas has worn) "Wrapped in your winter coat, you brave the cold. Everyone can see what you are: a courageous father who will not take 'no' for an answer.";
             
             if(verhaaltracker.status < 7 && kleding hasnt worn && jas hasnt worn) "Clad only in your nightshirt, you brave the cold. Everyone can see what you are: a courageous father who will not take 'no' for an answer.";
	       
	     if(verhaaltracker.status == 7)
	       "There you stand, naked of clothes, naked of illusions. Stripped bare to your rotting soul. You are Maartje's father. You are the baron. Villain or victim, monster or weakling? Can you change? Can you do anything to help her?";
             };
	   if(lm_n == 9) "^And there was darkness.";
	   if(lm_n == 17) "It's too dark; you can't see anything.";
	   if(lm_n == 30) "Either you cannot see such a thing, or you don't have to interact with it.";
	   if(lm_n == 5) "Do you want a RESTART, LOAD an old game, see the MENU (with information about the ideas behind ~The baron~) or QUIT reading the story?";
	     

	 Take:
	   if(lm_n == 2) 
	     if(verhaaltracker.status < 7 && verhaaltracker.status > 1) {
	       "Only the baron of M@:unchhausen can pull himself up, and that is not the baron you are looking for.";
	     }
	     else {
	       "You are a baron, but not that of M@:unchhausen.";
	     };
	     
          Pray:
	     if(verhaaltracker.status < 7 && verhaaltracker.status > 1){
	       "~Maria, holy mother, protect me on this quest,~ you murmur.";
	     }
	     else if (verhaaltracker.status == 1) {
	       "~For the glory of God!~, you exclaim.";
	     }
               "BUG: this should not occur, as all PRAY-commands in scene 7 are trapped by the rooms. Please report this bug.";
	     
	  Pull:
	    if(lm_n == 4) "That is not useful.";

          Sleep:          
	     if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	       "The prospect of deep and dreamless sleep is tempting--but first you have to save your daughter!";
	     }
	     else if (verhaaltracker.status == 1) {
	       "You are here to defeat the dragon, not to take a nap!";
	     }
	     else 
	       "You cannot escape that easily. The fire inside keeps you awake.";
	  
	  
	  Sing:           
	     if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	       "~Don Giovanni!~, you hear yourself sing in a deep, ominous bass. Indeed, it seems as if any moment now divine retribution will descend to earth to drag the lecherous villain of this piece down into the abyss of Hell.";
	     }
	     else if (verhaaltracker.status == 1) {
	       "You sing a violent battle song, about a knight who cuts an evil dragon to pieces.";
	     }
	     else 
	       "Your voice falters.";
	  
          Strong:         if(verhaaltracker.status < 7 && verhaaltracker.status > 1) {
	                     "You curse the evil baron for all he has done to you.";
                           }
	                  else if (verhaaltracker.status == 1) {
	                     "You curse the dragon.";
	                   }
                          else "You curse yourself.";       
	  
	  Think:          "Images flash before your mind's eye, but you push them away. You do not want to think.";

	  ThrowAt:
	    if(lm_n == 2) "That would solve nothing.";
	  
	  Touch:
	    if(lm_n == 1) "That would achieve nothing.";
	  
          Wait:          	     
	     if(verhaaltracker.status < 6){
	       "There is no time to lose.";
	     }
	     else 
	       "You tarry for a moment--but the night is too long and your lust is too strong.";
	   
	       
	  
	  Wake: "You cannot escape that easily from this dark nightmare.";

          WaveHands:      
	     if(verhaaltracker.status < 6){
	       "You jump up and down and move your arms a bit. You feel great. Full of strength that wishes to express itself.";
	     }
	     else 
	       "Your arms hang down as if they were made of lead.";

   
        ];